. With this script you can use LoView as DefaultTool
. 
.KEY name/A
.BRA {
.KET }

; Get the full path to LoView
Which >NIL: "LoView"
If Warn
  If Exists "ENV:LoView/LoViewPath"
    Set LoView `getenv LoView/LoViewPath`
  Else
    Which >NIL: RequestFile
    If not warn
      Set LoView `RequestFile title "Where is LoView installed ?" noicons`
      If "$LoView" eq ""
        Echo "Cannot find LoView."
        UnSet LoView
        Quit
      Else
        Set LoView `Which "$LoView"`
        SetEnv LoView/LoViewPath "$LoView"
        If not Exists "ENVARC:LoView"
          MakeDir >NIL: "ENVARC:LoView"
        EndIf
        Copy "ENV:LoView/LoViewPath" "ENVARC:LoView/LoViewPath" clone quiet
      EndIf
    EndIf
  EndIf
Else
  Set LoView `Which "LoView"`
EndIf

Set Image "{name}"
Set CurDir `CD`
Stack 32768
FailAt 21
CD >NIL: *>NIL: /
If val $RC eq 0
  FailAt 10
  Run >NIL: "$LoView" -file "$CurDir/$Image"
Else
  FailAt 10
  Run >NIL: "$LoView" -file "$CurDir$Image"
EndIf
CD "$CurDir"

UnSet CurDir
UnSet Image
UnSet LoView
Quit



